home/hosts/odin/users/thomas.nix

{ config, lib, pkgs, ... }:
{
  users.users.thomas = {
    isNormalUser = true;
    extraGroups = [
      "keys"
      "wheel"
      "users"
      "storage"
    ];
    shell = config.programs.fish.package;
    hashedPasswordFile = config.age.secrets."odin/users/thomas".path;
    openssh.authorizedKeys.keys = [
      "ssh-rsa AAAAB3NzaC1yc2EAAAADAQABAAACAQC5o7LT5wPYWgI8Mvr6RKOv+BcsbQgU7PCw2hheVu17alwF1uFUsAYV5BVQu+uv9uEm/UDsCNhfM6TwI0A1prdmtBz4pKiwXbj7fcdp6DcVOgTsPfawbXEpivtJvlhEatyTsR26MjHKnqpT0BxPvj6Ug6pvRkCYW5d2bWXiY9murmAX6Q5kSyNunkB8PdRTH+S47f7eOdCJY63VBOkkiG8M7XyPwFCDTYiHhbMZcejIdY9mB6kYnMQVRHDznQWiQxrcaE1fD/TY3db9GDcOVoo2aDBOZX7WT2+me67sU8dEK9+nSyhWDzBbEs8knu87ZlKPFwhl4slenRniKhbf22OpicXArtEcjEj0GyDJH5e+ZCIQ4eSQanA7TxnKFlDuaf+Qqx55UT+ya4vJJeik7nkzbRHaE9IoWhhiOaOnaN6kHIxuxB6z7EL3Gk7f78+I/qBaj5df6fgnXM3JBXKa5bRH2wqoSetJAo6EGpEgmU2huB1ktiGlO7BlF5XwSw6cb/KT7NSIXhncgLkCzsDVXxecVQv1FnPISBcp3+ti01ADVf2trgpPDbNTWV40Rgiefie0o2fc6KWAFfum1j5N3WWU+XVVmRjDmKKHiEJBLNKDAe0rQf+tryPW4c5GIN7aFoB+8dYFAuUyLd7Fu3vhZdmcckN5ryHunEc0dKPIiuoVZw=="
    ];
  };

  systemd.services.setup-home-manager =
    let
      git = lib.getExe' pkgs.git "git";
      nix = lib.getExe' pkgs.nix "nix";
    in
    {
      description = "Setup home-manager configuration for thomas";
      after = [ "network-online.target" ];
      wants = [ "network-online.target" ];
      wantedBy = [ "multi-user.target" ];

      serviceConfig = {
        Type = "oneshot";
        RemainAfterExit = true;
        User = "thomas";
        Group = "users";
      };

      path = [ pkgs.git pkgs.nix ];

      script = ''
        if [ ! -d "/home/thomas/workspace/control/home" ]; then
          echo "Setting up home environment..."
          mkdir -p "/home/thomas/workspace/control"
          cd "/home/thomas/workspace/control"
          ${git} clone https://codeberg.org/control/home.git
          cd home
          ${nix} run github:nix-community/home-manager -- switch -b backup --flake .#thomas@odin
        fi
      '';
    };
}