home/flake.nix

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11?shallow=true";
    nixpkgs-darwin.url = "github:nixos/nixpkgs/nixpkgs-25.11-darwin?shallow=true";
    nixpkgs-unstable.url = "github:nixos/nixpkgs/nixpkgs-unstable?shallow=true";

    nixos-facter-modules.url = "github:nix-community/nixos-facter-modules?shallow=true";
    # nixos-facter-modules.inputs.nixpkgs.follows = "nixpkgs";

    darwin.url = "github:lnl7/nix-darwin/nix-darwin-25.11?shallow=true";
    darwin.inputs.nixpkgs.follows = "nixpkgs-darwin";

    devenv.url = "github:cachix/devenv?shallow=true";
    devenv.inputs.nixpkgs.follows = "nixpkgs-unstable";

    home-manager.url = "github:nix-community/home-manager/master?shallow=true";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";

    nixvim.url = "github:nix-community/nixvim/main?shallow=true";
    nixvim.inputs.nixpkgs.follows = "nixpkgs-unstable";

    impermanence.url = "github:nix-community/impermanence?shallow=true";
    # impermanence.inputs.nixpkgs.follows = "nixpkgs";

    agenix.url = "github:ryantm/agenix?shallow=true";
    agenix.inputs.nixpkgs.follows = "nixpkgs";
    secrets.url = "git+ssh://[email protected]/control/secrets.git";
    # secrets.url = "path:/Users/thomas/workspace/control/secrets";

    disko.url = "github:nix-community/disko?shallow=true";
    disko.inputs.nixpkgs.follows = "nixpkgs";

    git-hooks.url = "github:cachix/git-hooks.nix";
    git-hooks.inputs.nixpkgs.follows = "nixpkgs";

    zen-browser.url = "github:0xc000022070/zen-browser-flake";
    zen-browser.inputs.nixpkgs.follows = "nixpkgs";
    zen-browser.inputs.home-manager.follows = "home-manager";

    firefox-addons.url = "gitlab:rycee/nur-expressions?dir=pkgs/firefox-addons";
    firefox-addons.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs =
    { self, ... }@inputs:
    let
      inherit (self) outputs;
    in
    rec {

      lib = import ./lib { inherit inputs outputs; };
      overlays = import ./overlays { inherit inputs outputs; };
      modules = import ./modules;

      formatter = lib.eachSystem (_system: pkgs: pkgs.nixfmt-tree);
      packages = lib.eachSystem (system: pkgs: import ./packages {
        inherit pkgs;
        nixvim = inputs.nixvim.legacyPackages.${system}.makeNixvimWithModule { };
      });
      devShells = lib.eachSystem (system: pkgs: import ./shell.nix {
        inherit pkgs system;
        # inherit (self.checks.${system}.pre-commit-check) shellHook;
        # inherit (self.checks.${system}.pre-commit-check) enabledPackages;
      });

      checks = lib.eachSystem (system: _pkgs: {
        pre-commit-check = inputs.git-hooks.lib.${system}.run {
          src = ./.;
          hooks = {
            deadnix.enable = true;
            nixpkgs-fmt.enable = true;
          };
        };
      });

      templates = {
        devenv = {
          path = ./templates/devenv;
          description = "A template for a devenv environment";
        };
      };

      homeConfigurations = {
        "thomas@meili" = lib.mkHome {
          system = "aarch64-darwin";
          modules = [ ./home/meili.nix ];
        };

        "thomas@modgud" = lib.mkHome {
          system = "x86_64-linux";
          modules = [ ./home/modgud.nix ];
        };

        "thomas@fedora" = lib.mkHome {
          system = "aarch64-linux";
          modules = [ ./home/fedora.nix ];
        };

        "thomas@odin" = lib.mkHome {
          system = "x86_64-linux";
          modules = [ ./home/odin.nix ];
        };
      };

      nixosConfigurations = {
        # heimdall = lib.mkSystem {
        #   system = "riscv64-linux";
        #   modules = [ ./hosts/heimdall ];
        # };
        #
        # modgud = lib.mkSystem {
        #   system = "x86_64-linux";
        #   modules = [ ./hosts/modgud ];
        # };

        odin = lib.mkSystem {
          system = "x86_64-linux";
          modules = [ ./hosts/odin ];
        };

        grist = lib.mkSystem {
          system = "x86_64-linux";
          modules = [ ./hosts/odin/containers/grist.nix ];
        };
      };

      darwinConfigurations = {
        meili = lib.mkDarwin {
          system = "aarch64-darwin";
          modules = [ ./hosts/meili ];
        };
      };
    };
}